Prefab Example

The following is the version of Greet program that simply illustrates the use of the Prefab module:

Program Listing 3-15 prefabgreet.b

1. implement PrefabGreet;
3. include "sys.m";
4. include "draw.m";
5. include "prefab.m";
7. sys: Sys;
8. draw: Draw;
9. Display, Font, Rect, Point, Image, Screen: import draw;
10. prefab: Prefab;
11. Style, Element, Compound, Environ: import prefab;
13. PrefabGreet : module {
14. init: fn(ctxt: ref Draw->Context, argv: list of string);
15. };
17. init(ctxt: ref Draw->Context, argv: list of string) {
18. sys = load Sys Sys->PATH;
19. draw = load Draw Draw->PATH;
20. prefab = load Prefab Prefab->PATH;
22. display := Display.allocate(nil);
23. disp := display.image;
24. spawn refresh(display);
25. white := display.color(Draw->White); #predefined color
26. yellow := display.color(Draw->Yellow); #predefined color
27. black := display.color(Draw->Black); #predefined color
28. grey := display.rgb(160,160,160);
29. ones := display.ones;
30. screen := Screen.allocate(disp, white, 1);
32. textfont := Font.open(display,
"/fonts/lucidasans/unicode.13.font");
33. titlefont := Font.open(display,
"/fonts/lucidasans/italiclatin1.10.font");
34. win_style := ref Style(
35. titlefont, # title font
36. textfont, # text font
37. grey, # element color
38. black, # edge color
39. yellow, # title color
40. black, # text color
41. white); # highlight color
43. win := ref Environ(screen, win_style);
45. if ((tl argv) != nil)
46. msg := "Hello, " + (hd(tl argv)) + "!";
47. else
48. msg = "Hello, World!";
50. icon := display.open("/icons/lucent.bit");
51. dy := (icon.r.dy()-textfont.height)/2;
52. wintitle := Element.text(win, "Inferno Prefab Example",
((0,0),(0,0)), Prefab->ETitle);
53. ie := Element.icon(win, icon.r, icon, ones);
54. te := Element.text(win, msg, ((0,dy),(0,dy)),
Prefab->EText);
55. se:= Element.separator(win, ((0,0), (10,0)),
display.zeros, display.zeros);
56. le := Element.elist(win, ie, Prefab->EHorizontal);
57. le.append(se); # add space between icon and text
58. le.append(te);
59. le.append(se); # add space between text and border
60. le.adjust(Prefab->Adjpack, Prefab->Adjleft);
62. c:= Compound.box(win, (20,20), wintitle, le);
63. c.draw();
64. sys->sleep(10000); # Prefab elements are gc'd
65. }
67. refresh(display: ref Display) {
68. display.startrefresh();
69. }

In addition to the the Display, Image, and Font types, this example uses a Screen object. Line 30 creates a new Screen object and stores it in screen. This becomes the foundation upon which elements, such as windows, are drawn.

Lines 34 through 41 defines the font and color information for the window that will be displayed.

Line 43 creates the window environment, based on the screen and style that have been defined.

Line 52 defines the title of the window. Lines 53 and 54 define the icon and text that will be displayed. Line 55 defines the space that will be used to pad the elements.

Line 56 sets layout of the elements to be a horizontal list. Lines 57 through 59 add the elements to the list in the appropriate order. Line 60 formats the elements.

Line 62 defines the box, or the window, that will be drawn. It contains the title and contents. Line 63 actually draws the window.

After compiling this program, you could run it from the Inferno console:

	inferno$ prefabgreet Inferno